Créer des utilisateurs et des tablespaces Oracle

SEI fournit des scripts SQL pour créer des utilisateurs dédiés et des tablespaces Oracle. Vous devez exécuter les scripts AVANT d'installer SEI. Cette étape est requise depuis la version 2022 R1.3.

Note

Ces scripts doivent être exécutés par un utilisateur ayant des droits d'administration sur le serveur.

Effectuez ces étapes générales :

Étape 1 : Révoquer les droits d'un utilisateur existant

Étape 2 : Créez l'utilisateur SEI et son schéma

Étape 3 : Créez l'utilisateur BILicense et son schéma

Étape 4 : Créez l'utilisateur SEICube

Étape 5 : Installez les paquets de SEI

Scénarios additionnels :

Vous pouvez ajouter de l'espace à la base de données Oracle au besoin.

Lorsque vous désinstallez SEI, vous pouvez supprimer les utilisateurs Oracle.

Cliquez ici pour voir des informations sur Oracle.

Étape 1 : Révoquer les droits d'un utilisateur existant

Si un utilisateur Oracle est déjà utilisé dans votre environnement SEI, vous devez révoquer ses droits avant de continuer.

Exécutez le script 0_RevokePermissions.sql.

Configurez le paramètre SEI_USER à SEI.

0_RevokePermissions.sql

Copier

/* Script to revoke permissions on existing users.
** 
** # Description
** The purpose of this script is to revoke the current permissions for a given user.
** 
** # Permissions
** 
** # How to use it
** - The script needs to be run from a user with administrative permissions on the server
** - Fill the variables after the comment `Change the values`
**   * SEI_USER: Name of the SEI user
**   * ENABLE_LOGING: Enable the script to print some logs
** - Run the script
*/

set serveroutput on;

DECLARE
    /*************************/
    /* Variables declaration */
    /*************************/
    SEI_USER                    VARCHAR2(1000);
    ENABLE_LOGING               BOOLEAN;
    -- Other variables
    v_SEI_USER_CHECK            NUMBER;

BEGIN
    /*********************/
    /* Change the values */
    /*********************/
    -- User information
    SEI_USER                       := 'SEI_SEED';
    -- Other
    ENABLE_LOGING                  := true;
        
    -- Enabling logs
    IF ( ENABLE_LOGING = true ) THEN
        dbms_output.enable(1000000);
    ELSE
        dbms_output.disable;
    END IF;
    
    /***********************************************************/
    /*                        Variables                        */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* Variables summary  */');
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('  SEI Username =>  ' || SEI_USER);
    dbms_output.new_line;
    
    /***********************************************************/
    /*                   TableSpace / Users                    */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/*    Permissions     */');
    dbms_output.put_line('/**********************/');
    -- Check if the user SEI Objects exists
    SELECT COUNT(1) INTO v_SEI_USER_CHECK FROM DBA_USERS WHERE USERNAME = SEI_USER;
    
    -- Creating user SEI Objects
    IF ( v_SEI_USER_CHECK <> 0 ) THEN
        dbms_output.put_line('/*******************************/');
        dbms_output.put_line('/*    Revoking Permissions     */');
        dbms_output.put_line('/*******************************/');
        
        dbms_output.put_line('  Revoking granted roles ...');
        for r in ( select * from dba_role_privs
                   where grantee = SEI_USER )
        loop
            EXECUTE IMMEDIATE 'revoke ' || r.granted_role ||' from ' || r.grantee;
            dbms_output.put_line('    Revoked: revoke ' || r.granted_role ||' from ' || r.grantee ||';');
        end loop;
        
        dbms_output.put_line('  Revoking granted system privileges ...');
        
        for r in ( select * from dba_sys_privs
                   where grantee = SEI_USER )
        loop
            EXECUTE IMMEDIATE 'revoke ' || r.privilege ||' from ' || r.grantee;
            dbms_output.put_line('    Revoked: revoke ' || r.privilege ||' from ' || r.grantee ||';');
        end loop;
        
        dbms_output.put_line('  Revoking granted access privileges ...');
        
        for r in ( select * from dba_tab_privs
                   where grantee = SEI_USER )
        loop
            EXECUTE IMMEDIATE 'revoke ' || r.privilege || ' on ' || r.owner||'.'||r.table_name ||' from ' || r.grantee;
            dbms_output.put_line('    Revoked: revoke ' || r.privilege || ' on ' || r.owner||'.'||r.table_name ||' from ' || r.grantee ||';');
        end loop;
    ELSE
        dbms_output.put_line('  The UserName "' || SEI_USER || ' doesn''t exists');
    END IF;
END;

Étape 2 : Créez l'utilisateur SEI et son schéma

Exécutez le script 1_ConfigDB.sql.

Configurez les paramètres comme ceci :
1. Le paramètre SEI_USER doit être réglé à SEI.
2. Le paramètre SEI_TABLE_SPACE devrait être réglé à SEI mais vous pouvez lui donner un autre nom.
3. Le paramètre SEI_TMP_TABLE_SPACE devrait être réglé à SEI_TMP mais vous pouvez lui donner un autre nom.
4. Configurez les autres paramètres selon vos besoins.

1_ConfigDB.sql

Copier

/* Script to create users for SEI.
** 
** # Description
** The purpose of this script is to create an user specific for the SEI application.
** The script will create an Oracle user with an associated TableSpace (or can use an existing one)
** This script should be run for SEI and BILICENSE users
** 
** # Permissions
** The SEI user will have all rights on his own schema only
** This script will remove all existing permissions on the existing user
** 
** # How to use it
** - The script needs to be run from a user with administrative permissions on the server
** - Fill the variables after the comment `Change the values`
**   * SEI_USER: Name of the SEI user
**   * SEI_USER_PWD: Password for the user
**   * SEI_TABLE_SPACE: Name of the main table space for the user
**   * SEI_TABLE_SPACE_LOG: Enable the logging for the main table space
**   * SEI_TABLE_SPACE_COMP: Enable the compression for the main table space (Compression has to be enabled server wide)
**   * SEI_TMP_TABLE_SPACE: Name of the temporary table space
**   * ENABLE_LOGING: Enable the script to print some logs
**   * REVOKE_EXIST_PERM: If the user already exists, define if we want to remove the permissions already granted
** - Run the script
*/

set serveroutput on;

DECLARE
    /*************************/
    /* Variables declaration */
    /*************************/
    SEI_USER                        VARCHAR2(1000);
    SEI_USER_PWD                    VARCHAR2(1000);
    SEI_TABLE_SPACE                 VARCHAR2(1000);
    SEI_TABLE_SPACE_LOG             BOOLEAN;
    SEI_TABLE_SPACE_COMP            BOOLEAN;
    SEI_TMP_TABLE_SPACE             VARCHAR2(1000);
    ENABLE_LOGING                   BOOLEAN;
    REVOKE_EXIST_PERM               BOOLEAN;
    -- Other variables
    v_CUSTOM_TABLE_SPACE_PATH       VARCHAR2(1000);
    v_SEI_USER_CHECK                NUMBER;
    v_SEI_TABLE_SPACE_LOG           VARCHAR2(1000);
    v_SEI_TABLE_SPACE_COMP          VARCHAR2(1000);
    TablespaceExistsExcep            EXCEPTION;
    FileExistsExcep                    EXCEPTION;
    PRAGMA EXCEPTION_INIT(TablespaceExistsExcep,-1543);
    PRAGMA EXCEPTION_INIT(FileExistsExcep,-1119);
BEGIN
    /*********************/
    /* Change the values */
    /*********************/
    -- User information
    SEI_USER                    := 'SEI';
    SEI_USER_PWD                := 'SEI_PWD';
     -- TableSpace information
    SEI_TABLE_SPACE             := 'SEI';
    SEI_TABLE_SPACE_LOG         := true;
    SEI_TABLE_SPACE_COMP        := false;
    
    SEI_TMP_TABLE_SPACE         := 'SEI_TMP';
    -- Other
    ENABLE_LOGING               := true;
    REVOKE_EXIST_PERM           := false;
    
    -- Getting custom datafile path
    SELECT VALUE INTO v_CUSTOM_TABLE_SPACE_PATH FROM v$parameter WHERE NAME ='db_create_file_dest' ;
    IF v_CUSTOM_TABLE_SPACE_PATH is not null THEN
        v_CUSTOM_TABLE_SPACE_PATH := v_CUSTOM_TABLE_SPACE_PATH || '/';
    END IF;
        
    -- Enabling logs
    IF ( ENABLE_LOGING = true ) THEN
        dbms_output.enable(1000000);
    ELSE
        dbms_output.disable;
    END IF;
    
    -- Preparing setting for the table spaces
    -- SEI
    IF ( SEI_TABLE_SPACE_LOG = true ) THEN
        v_SEI_TABLE_SPACE_LOG := '';
    ELSE
        v_SEI_TABLE_SPACE_LOG := ' NOLOGGING ';
    END IF;
    
    IF ( SEI_TABLE_SPACE_COMP = true ) THEN
        v_SEI_TABLE_SPACE_COMP := ' DEFAULT COMPRESS ';
    ELSE
        v_SEI_TABLE_SPACE_COMP := '';
    END IF;
    
    /***********************************************************/
    /*                        Variables                        */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* Variables summary  */');
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('  SEI Username =>  ' || SEI_USER);
    dbms_output.put_line('  SEI Password => ' || SEI_USER_PWD);
    dbms_output.put_line('  /* Table space informations */');
    dbms_output.put_line('    SEI TableSpace');
    dbms_output.put_line('      Name =>  ' || SEI_TABLE_SPACE);
    dbms_output.put_line('      Loging =>  ' || sys.diutil.bool_to_int(SEI_TABLE_SPACE_LOG));
    dbms_output.put_line('      Compression =>  ' || sys.diutil.bool_to_int(SEI_TABLE_SPACE_COMP));
    dbms_output.put_line('    SEI TMP TableSpace');
    dbms_output.put_line('      Name =>  ' || SEI_TMP_TABLE_SPACE);
    
    IF v_CUSTOM_TABLE_SPACE_PATH is not null THEN
        dbms_output.put_line('    Custom datafile path detected =>  ' || v_CUSTOM_TABLE_SPACE_PATH);
    END IF;
    dbms_output.new_line;
    
    /***********************************************************/
    /*                   TableSpace / Users                    */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* TableSpace / Users */');
    dbms_output.put_line('/**********************/');
    -- Check if the user SEI exists
    SELECT COUNT(1) INTO v_SEI_USER_CHECK FROM DBA_USERS WHERE USERNAME = SEI_USER;
    
    -- Main TableSpace
    IF SEI_TABLE_SPACE is not null THEN
        BEGIN
            EXECUTE IMMEDIATE 'CREATE TABLESPACE '
                                  || SEI_TABLE_SPACE
                                  || ' DATAFILE '''
                                  || v_CUSTOM_TABLE_SPACE_PATH || SEI_TABLE_SPACE
                                  || '.DBF'' SIZE 1024M AUTOEXTEND ON MAXSIZE 32767M'
                                  || v_SEI_TABLE_SPACE_COMP
                                  || v_SEI_TABLE_SPACE_LOG;
            dbms_output.put_line('  TableSpace "' || SEI_TABLE_SPACE || '" created');
        EXCEPTION
            WHEN TablespaceExistsExcep THEN
                dbms_output.put_line('  The TableSpace "' || SEI_TABLE_SPACE || '" already exists');
                NULL;
            WHEN FileExistsExcep THEN
                dbms_output.put_line('  The file associated to the TableSpace "' || SEI_TABLE_SPACE || '" already exists');
                NULL;
        END;
    ELSE
        dbms_output.put_line('  The SEI_TABLE_SPACE variable was not filled so tablespace will not be created');
    END IF;
    
    -- Temp TableSpace
    IF SEI_TMP_TABLE_SPACE is not null THEN
        BEGIN
            EXECUTE IMMEDIATE 'CREATE TEMPORARY TABLESPACE '
                                  || SEI_TMP_TABLE_SPACE
                                  || ' TEMPFILE '''
                                  || v_CUSTOM_TABLE_SPACE_PATH || SEI_TMP_TABLE_SPACE
                                  || '.DBF'' SIZE 1024M AUTOEXTEND ON MAXSIZE 32767M';                                
            dbms_output.put_line('  TableSpace "' || SEI_TMP_TABLE_SPACE || '" created');
        EXCEPTION
            WHEN TablespaceExistsExcep THEN
                dbms_output.put_line('  The TableSpace "' || SEI_TMP_TABLE_SPACE || '" already exists');
            NULL;
            WHEN FileExistsExcep THEN
                dbms_output.put_line('  The file associated to the TableSpace "' || SEI_TMP_TABLE_SPACE || '" already exists');
            NULL;
        END;
    ELSE
        dbms_output.put_line('  The SEI_TMP_TABLE_SPACE variable was not filled so tablespace will not be created');
    END IF;
    
    -- Creating user SEI
    IF ( v_SEI_USER_CHECK = 0 ) THEN
        EXECUTE IMMEDIATE 'CREATE USER '
                          || SEI_USER
                          || ' IDENTIFIED BY '
                          || SEI_USER_PWD
                          || '  DEFAULT TABLESPACE '
                          || SEI_TABLE_SPACE
                          || ' TEMPORARY TABLESPACE '
                          || SEI_TMP_TABLE_SPACE
                          || ' QUOTA UNLIMITED ON '
                          || SEI_TABLE_SPACE;
        dbms_output.put_line('  UserName "' || SEI_USER || ' created');
    ELSE
        dbms_output.put_line('  The UserName "' || SEI_USER || ' already exists');

        IF ( REVOKE_EXIST_PERM = true ) THEN
            dbms_output.put_line('/*******************************/');
            dbms_output.put_line('/*    Revoking Permissions     */');
            dbms_output.put_line('/*******************************/');
            
            dbms_output.put_line('  Revoking granted roles ...');
            for r in ( select * from dba_role_privs
                    where grantee = SEI_USER )
            loop
                EXECUTE IMMEDIATE 'revoke ' || r.granted_role ||' from ' || r.grantee;
                dbms_output.put_line('    Revoked: revoke ' || r.granted_role ||' from ' || r.grantee ||';');
            end loop;
            
            dbms_output.put_line('  Revoking granted system privileges ...');
            
            for r in ( select * from dba_sys_privs
                    where grantee = SEI_USER )
            loop
                EXECUTE IMMEDIATE 'revoke ' || r.privilege ||' from ' || r.grantee;
                dbms_output.put_line('    Revoked: revoke ' || r.privilege ||' from ' || r.grantee ||';');
            end loop;
            
            dbms_output.put_line('  Revoking granted access privileges ...');
            
            for r in ( select * from dba_tab_privs
                    where grantee = SEI_USER )
            loop
                EXECUTE IMMEDIATE 'revoke ' || r.privilege || ' on ' || r.owner||'.'||r.table_name ||' from ' || r.grantee;
                dbms_output.put_line('    Revoked: revoke ' || r.privilege || ' on ' || r.owner||'.'||r.table_name ||' from ' || r.grantee ||';');
            end loop;
        ELSE
            dbms_output.put_line('  Current permissions of "' || SEI_USER || ' won''t be impacted');
        END IF;
        
    END IF;
    
    /***********************************************************/
    /*                       Permissions                       */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/*    Permissions     */');
    dbms_output.put_line('/**********************/');
    
    -- Grant General Authorization for SEI
    EXECUTE IMMEDIATE 'GRANT CREATE PROCEDURE, CREATE SESSION, CREATE TABLE, CONNECT, CREATE TYPE, CREATE VIEW, CREATE SYNONYM, CREATE TRIGGER, RESOURCE TO '
    || SEI_USER;
    dbms_output.put_line('  Username '|| SEI_USER || ' has been granted the following permissions on his own shemas:');
    dbms_output.put_line('    - CREATE PROCEDURE');
    dbms_output.put_line('    - CREATE SESSION');
    dbms_output.put_line('    - CREATE TABLE');
    dbms_output.put_line('    - CONNECT');
    dbms_output.put_line('    - CREATE TYPE');
    dbms_output.put_line('    - CREATE VIEW');
    dbms_output.put_line('    - CREATE SYNONYM');
    dbms_output.put_line('    - CREATE TRIGGER');
END;

Étape 3 : Créez l'utilisateur BILicense et son schéma

Exécutez le script 1_ConfigDB.sql à nouveau.

Configurez les paramètres comme ceci :
1. Le paramètre SEI_USER doit être réglé à BILicense.
2. Le paramètre SEI_TABLE_SPACE devrait être réglé à BILicense mais vous pouvez lui donner un autre nom.
3. Le paramètre SEI_TMP_TABLE_SPACE devrait être réglé à BILicense_TMP mais vous pouvez lui donner un autre nom.
4. Configurez les autres paramètres selon vos besoins.

Étape 4 : Créez l'utilisateur SEICube

Cet utilisateur aura accès aux données du cube ; cela inclut l'accès à tous les schémas (utilisateurs). Vous pouvez exclure l'accès à des tables spécifiques.

Exécutez le script 2_DataDB.sql.

Configurez les autres paramètres selon vos besoins en fonction des instructions mentionnées dans le script. Assurez-vous de fournir les autorisations d'accès en utilisant ces paramètres :
- SCHEMA_LIST
- EXCLUSION_TB_LIST
- EXCLUSION_VW_LIST

2_DataDB.sql

Copier

/* Script to create users for SEI Cube.
** 
** # Description
** The purpose of this script is to create an user specific for the SEI application.
** The script will create an Oracle user with an associated TableSpace (or can use an existing one)
** The script will also give some permissions on other schemas (users)
** 
** # Permissions
** The SEI_SEED user will have all rights on his own schema
** The SEI_SEED user will have the right to read all tables from the specified schema in the variable `SCHEMA_LIST`
** The SEI_SEED user will have the right to read all views from the specified schema in the variable `SCHEMA_LIST`
** The SEI_SEED user will have the right to create any trigger across the database
** It will be possible to specify some exclusions tables/views to not give access, see more info in the How to use it section
** This script will remove all existing permissions on the existing user
** 
** # How to use it
** - The script needs to be run from a user with administrative permissions on the server
** - Fill the variables after the comment `Change the values`
**   * SEI_CUSTOM_USER: Name of the SEI Cube user
**   * SEI_CUSTOM_USER_PWD: Password for the user
**   * SEI_CUSTOM_TABLE_SPACE: Name of the main table space for the user
**   * SEI_CUSTOM_TABLE_SPACE_LOG: Enable the logging for the main table space
**   * SEI_CUSTOM_TABLE_SPACE_COMP: Enable the compression for the main table space (Compression has to be enabled server wide)
**   * SEI_CUSTOM_TMP_TABLE_SPACE: Name of the temporary table space
**   * ENABLE_LOGING: Enable the script to print some logs
**   * REVOKE_EXIST_PERM: If the user already exists, define if we want to remove the permissions already granted
**
**   The following parameters are for the permissions
**   * SCHEMA_LIST: List of the schemas (users) tables/views that our user will be able to READ (SELECT) only
**   * EXCLUSION_TB_LIST: List of the tables to exclude for the grant select. Format is "SCHEMA"."TABLE"
**   * EXCLUSION_VW_LIST: List of the views to exclude for the grant select. Format is "SCHEMA"."VIEW"
** - Run the script
**
** # Things to know
** !!! In Oracle, to give the READ access on another schema, we need to do it table by table.
**     => By doing so the grants are point in time and if new tables are added in the future, the script will need to be re-run (it will only update the table grants).
** !!! In Oracle, to give the CREATE TABLE/TRIGGER permission on another schema, the user needs to have a server wide permission so it can create them in amy schema.
*/

set serveroutput on;

DECLARE
    /*************************/
    /* Variables declaration */
    /*************************/
    SEI_CUSTOM_USER                 VARCHAR2(1000);
    SEI_CUSTOM_USER_PWD             VARCHAR2(1000);
    SEI_CUSTOM_TABLE_SPACE          VARCHAR2(1000);
    SEI_CUSTOM_TABLE_SPACE_LOG      BOOLEAN;
    SEI_CUSTOM_TABLE_SPACE_COMP     BOOLEAN;
    SEI_CUSTOM_TMP_TABLE_SPACE      VARCHAR2(1000);
    SCHEMA_LIST                     dbms_sql.varchar2_table;
    EXCLUSION_TB_LIST               dbms_sql.varchar2_table;
    EXCLUSION_VW_LIST               dbms_sql.varchar2_table;
    ENABLE_LOGING                   BOOLEAN;
    REVOKE_EXIST_PERM               BOOLEAN;
    -- Other variables
    v_CUSTOM_TABLE_SPACE_PATH       VARCHAR2(1000);
    v_SEI_CUSTOM_USER_CHECK         NUMBER;
    v_SEI_CUSTOM_TABLE_SPACE_LOG    VARCHAR2(1000);
    v_SEI_CUSTOM_TABLE_SPACE_COMP   VARCHAR2(1000);
    v_SEI_CUSTOM_TMP_TS_COMP        VARCHAR2(1000);
    TablespaceExistsExcep            EXCEPTION;
    FileExistsExcep                    EXCEPTION;
    PRAGMA EXCEPTION_INIT(TablespaceExistsExcep,-1543);
    PRAGMA EXCEPTION_INIT(FileExistsExcep,-1119);
BEGIN
    /*********************/
    /* Change the values */
    /*********************/
    -- User information
    SEI_CUSTOM_USER                     := 'SEI_SEED';
    SEI_CUSTOM_USER_PWD                 := 'SEI_SEED_PWD';
     -- TableSpace information
    SEI_CUSTOM_TABLE_SPACE              := 'SEI_SEED';
    SEI_CUSTOM_TABLE_SPACE_LOG          := true;
    SEI_CUSTOM_TABLE_SPACE_COMP         := false;
    
    SEI_CUSTOM_TMP_TABLE_SPACE          := 'SEI_SEED_TMP';
    -- List of schemas
    SCHEMA_LIST(1)                      := 'X3FOLDER';
    -- Exclusion list
    --EXCLUSION_TB_LIST(1)                := '"X3FOLDER"."TABLE"';
    --EXCLUSION_VW_LIST(1)                := '"X3FOLDER"."VIEW"';
    -- Other
    ENABLE_LOGING                       := true;
    REVOKE_EXIST_PERM                   := false;
    
    -- Getting custom datafile path
    SELECT VALUE INTO v_CUSTOM_TABLE_SPACE_PATH FROM v$parameter WHERE NAME ='db_create_file_dest' ;
    IF v_CUSTOM_TABLE_SPACE_PATH is not null THEN
        v_CUSTOM_TABLE_SPACE_PATH := v_CUSTOM_TABLE_SPACE_PATH || '/';
    END IF;
        
    -- Enabling logs
    IF ( ENABLE_LOGING = true ) THEN
        dbms_output.enable(1000000);
    ELSE
        dbms_output.disable;
    END IF;
    
    -- Preparing setting for the table spaces
    -- SEI Objetcs
    IF ( SEI_CUSTOM_TABLE_SPACE_LOG = true ) THEN
        v_SEI_CUSTOM_TABLE_SPACE_LOG := '';
    ELSE
        v_SEI_CUSTOM_TABLE_SPACE_LOG := ' NOLOGGING ';
    END IF;
    
    IF ( SEI_CUSTOM_TABLE_SPACE_COMP = true ) THEN
        v_SEI_CUSTOM_TABLE_SPACE_COMP := ' DEFAULT COMPRESS ';
    ELSE
        v_SEI_CUSTOM_TABLE_SPACE_COMP := '';
    END IF;
    
    /***********************************************************/
    /*                        Variables                        */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* Variables summary  */');
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('  SEI Objects Username =>  ' || SEI_CUSTOM_USER);
    dbms_output.put_line('  SEI Objects Password => ' || SEI_CUSTOM_USER_PWD);
    dbms_output.put_line('  /* Table space informations */');
    dbms_output.put_line('    SEI Objects TableSpace');
    dbms_output.put_line('      Name =>  ' || SEI_CUSTOM_TABLE_SPACE);
    dbms_output.put_line('      Loging =>  ' || sys.diutil.bool_to_int(SEI_CUSTOM_TABLE_SPACE_LOG));
    dbms_output.put_line('      Compression =>  ' || sys.diutil.bool_to_int(SEI_CUSTOM_TABLE_SPACE_COMP));
    dbms_output.put_line('    SEI Objects TMP TableSpace');
    dbms_output.put_line('      Name =>  ' || SEI_CUSTOM_TMP_TABLE_SPACE);
    IF v_CUSTOM_TABLE_SPACE_PATH is not null THEN
        dbms_output.put_line('    Custom datafile path detected =>  ' || v_CUSTOM_TABLE_SPACE_PATH);
    END IF;
    FOR i IN SCHEMA_LIST.FIRST .. SCHEMA_LIST.LAST
    LOOP
        dbms_output.put_line('  Schemas =>  ' || SCHEMA_LIST(i));
    END LOOP;
    IF EXCLUSION_TB_LIST.count > 0 THEN
        FOR i IN EXCLUSION_TB_LIST.FIRST .. EXCLUSION_TB_LIST.LAST
        LOOP
            dbms_output.put_line('  Exclusion tables =>  ' || EXCLUSION_TB_LIST(i));
        END LOOP;
    END IF;
    IF EXCLUSION_VW_LIST.count > 0 THEN
        FOR i IN EXCLUSION_VW_LIST.FIRST .. EXCLUSION_VW_LIST.LAST
        LOOP
            dbms_output.put_line('  Exclusion views =>  ' || EXCLUSION_VW_LIST(i));
        END LOOP;
    END IF;
    dbms_output.new_line;
    
    /***********************************************************/
    /*                   TableSpace / Users                    */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* TableSpace / Users */');
    dbms_output.put_line('/**********************/');
    -- Check if the user SEI Objects exists
    SELECT COUNT(1) INTO v_SEI_CUSTOM_USER_CHECK FROM DBA_USERS WHERE USERNAME = SEI_CUSTOM_USER;
    
    -- Main TableSpace
    IF SEI_CUSTOM_TABLE_SPACE is not null THEN
        BEGIN
            EXECUTE IMMEDIATE 'CREATE TABLESPACE '
                                  || SEI_CUSTOM_TABLE_SPACE
                                  || ' DATAFILE '''
                                  || v_CUSTOM_TABLE_SPACE_PATH || SEI_CUSTOM_TABLE_SPACE
                                  || '.DBF'' SIZE 1024M AUTOEXTEND ON MAXSIZE 32767M'
                                  || v_SEI_CUSTOM_TABLE_SPACE_COMP
                                  || v_SEI_CUSTOM_TABLE_SPACE_LOG;
            dbms_output.put_line('  TableSpace "' || SEI_CUSTOM_TABLE_SPACE || '" created');
        EXCEPTION
            WHEN TablespaceExistsExcep THEN
                dbms_output.put_line('  The TableSpace "' || SEI_CUSTOM_TABLE_SPACE || '" already exists');
            NULL;
            WHEN FileExistsExcep THEN
                dbms_output.put_line('  The file associated to the TableSpace "' || SEI_CUSTOM_TABLE_SPACE || '" already exists');
            NULL;
        END;
    ELSE
        dbms_output.put_line('  The SEI_CUSTOM_TABLE_SPACE variable was not filled so tablespace will not be created');
    END IF;
    
    -- Temp TableSpace
    IF SEI_CUSTOM_TMP_TABLE_SPACE is not null THEN
        BEGIN
            EXECUTE IMMEDIATE 'CREATE TEMPORARY TABLESPACE '
                                  || SEI_CUSTOM_TMP_TABLE_SPACE
                                  || ' TEMPFILE '''
                                  || v_CUSTOM_TABLE_SPACE_PATH || SEI_CUSTOM_TMP_TABLE_SPACE
                                  || '.DBF'' SIZE 1024M AUTOEXTEND ON MAXSIZE 32767M';
            dbms_output.put_line('  TableSpace "' || SEI_CUSTOM_TMP_TABLE_SPACE || '" created');
        EXCEPTION
            WHEN TablespaceExistsExcep THEN
                dbms_output.put_line('  The TableSpace "' || SEI_CUSTOM_TMP_TABLE_SPACE || '" already exists');
            NULL;
            WHEN FileExistsExcep THEN
                dbms_output.put_line('  The file associated to the TableSpace "' || SEI_CUSTOM_TMP_TABLE_SPACE || '" already exists');
            NULL;
        END;
    ELSE
        dbms_output.put_line('  The SEI_CUSTOM_TMP_TABLE_SPACE variable was not filled so tablespace will not be created');
    END IF;
    
    -- Creating user SEI Objects
    IF ( v_SEI_CUSTOM_USER_CHECK = 0 ) THEN
        EXECUTE IMMEDIATE 'CREATE USER '
                          || SEI_CUSTOM_USER
                          || ' IDENTIFIED BY '
                          || SEI_CUSTOM_USER_PWD
                          || '  DEFAULT TABLESPACE '
                          || SEI_CUSTOM_TABLE_SPACE
                          || ' TEMPORARY TABLESPACE '
                          || SEI_CUSTOM_TMP_TABLE_SPACE
                          || ' QUOTA UNLIMITED ON '
                          || SEI_CUSTOM_TABLE_SPACE;
        dbms_output.put_line('  UserName "' || SEI_CUSTOM_USER || ' created');
    ELSE
        dbms_output.put_line('  The UserName "' || SEI_CUSTOM_USER || ' already exists');

        IF ( REVOKE_EXIST_PERM = true ) THEN
            dbms_output.put_line('/*******************************/');
            dbms_output.put_line('/*    Revoking Permissions     */');
            dbms_output.put_line('/*******************************/');
            
            dbms_output.put_line('  Revoking granted roles ...');
            for r in ( select * from dba_role_privs
                    where grantee = SEI_CUSTOM_USER )
            loop
                EXECUTE IMMEDIATE 'revoke ' || r.granted_role ||' from ' || r.grantee;
                dbms_output.put_line('    Revoked: revoke ' || r.granted_role ||' from ' || r.grantee ||';');
            end loop;
            
            dbms_output.put_line('  Revoking granted system privileges ...');
            
            for r in ( select * from dba_sys_privs
                    where grantee = SEI_CUSTOM_USER )
            loop
                EXECUTE IMMEDIATE 'revoke ' || r.privilege ||' from ' || r.grantee;
                dbms_output.put_line('    Revoked: revoke ' || r.privilege ||' from ' || r.grantee ||';');
            end loop;
            
            dbms_output.put_line('  Revoking granted access privileges ...');
            
            for r in ( select * from dba_tab_privs
                    where grantee = SEI_CUSTOM_USER )
            loop
                EXECUTE IMMEDIATE 'revoke ' || r.privilege || ' on ' || r.owner||'.'||r.table_name ||' from ' || r.grantee;
                dbms_output.put_line('    Revoked: revoke ' || r.privilege || ' on ' || r.owner||'.'||r.table_name ||' from ' || r.grantee ||';');
            end loop;
        ELSE
            dbms_output.put_line('  Current permissions of "' || SEI_CUSTOM_USER || ' won''t be impacted');
        END IF;
    END IF;
    
    /***********************************************************/
    /*                       Permissions                       */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/*    Permissions     */');
    dbms_output.put_line('/**********************/');
    
    -- Grant General Authorization for SEI Objects
    EXECUTE IMMEDIATE 'GRANT CREATE PROCEDURE, CREATE SESSION, CREATE TABLE, CONNECT, CREATE TYPE, CREATE VIEW, CREATE SYNONYM, CREATE TRIGGER, RESOURCE TO '
    || SEI_CUSTOM_USER;
    dbms_output.put_line('  Username '|| SEI_CUSTOM_USER || ' has been granted the following permissions on his own shemas:');
    dbms_output.put_line('    - CREATE PROCEDURE');
    dbms_output.put_line('    - CREATE SESSION');
    dbms_output.put_line('    - CREATE TABLE');
    dbms_output.put_line('    - CONNECT');
    dbms_output.put_line('    - CREATE TYPE');
    dbms_output.put_line('    - CREATE VIEW');
    dbms_output.put_line('    - CREATE SYNONYM');
    dbms_output.put_line('    - CREATE TRIGGER');
    
    -- Grant Trigger Authorization for SEI Objects
    EXECUTE IMMEDIATE 'GRANT CREATE ANY TRIGGER TO ' || SEI_CUSTOM_USER;
    dbms_output.put_line('  Username '|| SEI_CUSTOM_USER || ' has been granted the CREATE ANY TRIGGER permissions');
    dbms_output.put_line('    !!! The CREATE ANY TRIGGER applies server wide !!!');
    
    -- Grant READ permission on schemas for SEI Objects users
    FOR i IN SCHEMA_LIST.FIRST .. SCHEMA_LIST.LAST
    LOOP
        dbms_output.put_line('  Iterating on tables for schema ' || SCHEMA_LIST(i));
        FOR x IN (
            SELECT table_name FROM dba_all_tables WHERE owner = SCHEMA_LIST(i)
        ) LOOP
            EXECUTE IMMEDIATE 'GRANT SELECT ON "'
                              || SCHEMA_LIST(i)
                              || '"."'
                              || x.table_name
                              || '" TO '
                              || SEI_CUSTOM_USER;
            dbms_output.put_line('    Granting SELECT permissions on '
                                 || SCHEMA_LIST(i)
                                 || '.'
                                 || x.table_name);
        END LOOP;
        dbms_output.put_line('  Iterating on views for schema ' || SCHEMA_LIST(i));
        FOR x IN (
            SELECT
                view_name
            FROM
                dba_views
            WHERE
                    owner = SCHEMA_LIST(i)
                AND view_name <> 'LEGGTEYGRP'
        ) LOOP
            EXECUTE IMMEDIATE 'GRANT SELECT ON "'
                              || SCHEMA_LIST(i)
                              || '"."'
                              || x.view_name
                              || '" TO '
                              || SEI_CUSTOM_USER;
            dbms_output.put_line('  Granting SELECT permissions on '
                                 || SCHEMA_LIST(i)
                                 || '.'
                                 || x.view_name);
        END LOOP;
    END LOOP;
    
    -- Revoking permissions
    dbms_output.put_line('  Revoking permissions');
    IF EXCLUSION_TB_LIST.count > 0 THEN
        FOR i IN EXCLUSION_TB_LIST.FIRST .. EXCLUSION_TB_LIST.LAST
        LOOP
            EXECUTE IMMEDIATE 'REVOKE SELECT ON '
                                  || EXCLUSION_TB_LIST(i)
                                  || ' FROM '
                                  || SEI_CUSTOM_USER;
            dbms_output.put_line('    Revoking select access for table ' || EXCLUSION_TB_LIST(i));
        END LOOP;
    END IF;
    IF EXCLUSION_VW_LIST.count > 0 THEN
        FOR i IN EXCLUSION_VW_LIST.FIRST .. EXCLUSION_VW_LIST.LAST
        LOOP
            EXECUTE IMMEDIATE 'REVOKE SELECT ON '
                                  || EXCLUSION_TB_LIST(i)
                                  || ' FROM '
                                  || SEI_CUSTOM_USER;
            dbms_output.put_line('    Revoking select access for view ' || EXCLUSION_VW_LIST(i));
        END LOOP;
    END IF;
END;

Étape 5 : Installez les paquets de SEI

Après avoir créé les utilisateurs Oracle, vous devez exécuter les paquets d'installation de SEI pour créer les tables d'Oracle.

Effectuez les étapes pour installer le serveur de licences.
Effectuez les étapes pour installer le Central Point.
Effectuez les étapes pour installer l'installation SEI (installation de base ou avancée).

Scénarios additionnels

Ajoutez de l'espace à la base de données Oracle

Si vous avez besoin d'ajouter de l'espace supplémentaire à une table, vous pouvez exécuter le script ci-dessous pour ajouter 32 Go d'espace.

Exécutez le script 3_AddNewDataFile.sql.

Définissez ces paramètres comme décrit dans les instructions du script :
- TABLE_SPACE
- DATA_FILE_NAME
- ENABLE_LOGING

3_AddNewDataFile.sql

Copier

/* Script to add a new datafile to an existing table space.
** 
** # Description
** The purpose of this script is to add a new datafile to a table space to avoid storage issue.
** 
** # How to use it
** - The script needs to be run from a user with administrative permissions on the server
** - Fill the variables after the comment `Change the values`
**   * TABLE_SPACE: Name of the table space to update
**   * DATA_FILE_NAME: Name of the data file to add
**   * ENABLE_LOGING: Enable the script to print some logs
** - Run the script
**
** # Things to know
** !!! You can change the size, maxsize, etc. directly in the script to accomodate your need
*/

set serveroutput on;

DECLARE
    /*************************/
    /* Variables declaration */
    /*************************/
    TABLE_SPACE             VARCHAR2(1000);
    DATA_FILE_NAME          VARCHAR2(1000);
    ENABLE_LOGING           BOOLEAN;
    -- Other variables
    v_CUSTOM_TABLE_SPACE_PATH       VARCHAR2(1000);
    TablespaceExistsExcep    EXCEPTION;
    FileExistsExcep            EXCEPTION;
    PRAGMA EXCEPTION_INIT(TablespaceExistsExcep,-1543);
    PRAGMA EXCEPTION_INIT(FileExistsExcep,-1537);
BEGIN
    /*********************/
    /* Change the values */
    /*********************/
    TABLE_SPACE         := 'SEI_SEED';
    DATA_FILE_NAME      := 'SEI_SEED_NEW2';
    ENABLE_LOGING       := true;
    
    -- Enabling logs
    IF ( ENABLE_LOGING = true ) THEN
        dbms_output.enable(1000000);
    ELSE
        dbms_output.disable;
    END IF;
    
    -- Getting custom datafile path
    SELECT VALUE INTO v_CUSTOM_TABLE_SPACE_PATH FROM v$parameter WHERE NAME ='db_create_file_dest' ;
    IF v_CUSTOM_TABLE_SPACE_PATH is not null THEN
        v_CUSTOM_TABLE_SPACE_PATH := v_CUSTOM_TABLE_SPACE_PATH || '/';
    END IF;
    
    /***********************************************************/
    /*                        Variables                        */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* Variables summary  */');
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('  Table space name =>  ' || TABLE_SPACE);
    dbms_output.put_line('  Datafile name =>  ' || DATA_FILE_NAME);
    IF v_CUSTOM_TABLE_SPACE_PATH is not null THEN
        dbms_output.put_line('    Custom datafile path detected =>  ' || v_CUSTOM_TABLE_SPACE_PATH);
    END IF;
    
    /***********************************************************/
    /*                 TableSpace / Datafile                   */
    /***********************************************************/
    dbms_output.put_line('/*************************/');
    dbms_output.put_line('/* TableSpace / Datafile */');
    dbms_output.put_line('/*************************/');
    IF TABLE_SPACE is not null THEN
        IF DATA_FILE_NAME is not null THEN
            BEGIN
                EXECUTE IMMEDIATE 'ALTER TABLESPACE '
                                      || TABLE_SPACE
                                      || ' ADD DATAFILE '''
                                      || v_CUSTOM_TABLE_SPACE_PATH || DATA_FILE_NAME
                                      || '.DBF'' SIZE 1024M AUTOEXTEND ON MAXSIZE 32767M';
                dbms_output.put_line('  TableSpace "' || TABLE_SPACE || '" updated to use also the datafile ' || v_CUSTOM_TABLE_SPACE_PATH || DATA_FILE_NAME || '.DBF');
            EXCEPTION
                WHEN TablespaceExistsExcep THEN
                    dbms_output.put_line('  The TableSpace "' || TABLE_SPACE || '" already exists');
                NULL;
                WHEN FileExistsExcep THEN
                    dbms_output.put_line('  The date file "' || DATA_FILE_NAME || '" already exists');
                NULL;
            END;
        ELSE
            dbms_output.put_line('  The DATA_FILE_NAME variable was not filled so databfile will not be created');
        END IF;
    ELSE
        dbms_output.put_line('  The TABLE_SPACE variable was not filled so tablespace will not be updated');
    END IF;
END;

Supprimer des utilisateurs Oracle

Désinstallez SEI avec les paquets d'installation.
Exécutez le script 9_UninstallDB.sql autant de fois que nécessaire pour supprimer chaque utilisateur.

9_UninstallDB.sql

Copier

/* Script to uninstall users.
** 
** # Description
** The purpose of this script is to properly uninstall a SEI user.
** 
** # How to use it
** - The script needs to be run from a user with administrative permissions on the server
** - Fill the variables after the comment `Change the values`
**   * SEI_USER: Name of the SEI Cube user
**   * ENABLE_LOGING: Enable the script to print some logs
** - Run the script
*/

set serveroutput on;

DECLARE
    /*************************/
    /* Variables declaration */
    /*************************/
    SEI_USER                   VARCHAR2(1000);
    SEI_TABLE_SPACE            VARCHAR2(1000);
    SEI_TMP_TABLE_SPACE        VARCHAR2(1000);
    ENABLE_LOGING              BOOLEAN;
    -- Other variables
    v_SEI_USER_CHECK           NUMBER;
    TablespaceDOESNTExistsExcep       EXCEPTION;
    PRAGMA EXCEPTION_INIT(TablespaceDOESNTExistsExcep,-959);
BEGIN
    /*********************/
    /* Change the values */
    /*********************/
    -- User information
    SEI_USER                    := 'SEI';
    -- TableSpace information
    SEI_TABLE_SPACE             := 'SEI';
    SEI_TMP_TABLE_SPACE         := 'SEI_TMP';
    -- Other
    ENABLE_LOGING               := true;
    
    -- Enabling logs
    IF ( ENABLE_LOGING = true ) THEN
        dbms_output.enable(1000000);
    ELSE
        dbms_output.disable;
    END IF;

    /***********************************************************/
    /*                        Variables                        */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* Variables summary  */');
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('  SEI Objects Username =>  ' || SEI_USER);
    dbms_output.put_line('  /* Table space informations */');
    dbms_output.put_line('    SEI TableSpace');
    dbms_output.put_line('      Name =>  ' || SEI_TABLE_SPACE);
    dbms_output.put_line('    SEI TMP TableSpace');
    dbms_output.put_line('      Name =>  ' || SEI_TMP_TABLE_SPACE);
    dbms_output.new_line;
    
    /***********************************************************/
    /*                   TableSpace / Users                    */
    /***********************************************************/
    dbms_output.put_line('/**********************/');
    dbms_output.put_line('/* TableSpace / Users */');
    dbms_output.put_line('/**********************/');
    -- Check if the user SEI Objects exists
    SELECT COUNT(1) INTO v_SEI_USER_CHECK FROM DBA_USERS WHERE USERNAME = SEI_USER;
    
    -- User
    IF ( v_SEI_USER_CHECK = 1 ) THEN
        -- Killing sessions
        FOR r IN (select sid,serial# from v$session where username = SEI_USER)
        LOOP
            EXECUTE IMMEDIATE 'ALTER SYSTEM KILL SESSION ''' || r.sid  || ',' 
                || r.serial# || ''' IMMEDIATE';
            dbms_output.put_line('  Killing session with serial "' || r.serial# || ' for user ' || SEI_USER);
        END LOOP;
        -- Can be usefull to manually kill the session
        --SELECT 'ALTER SYSTEM KILL SESSION '''||sid||','||serial#||''' IMMEDIATE;' FROM v$session where username=SEI_USER;
        EXECUTE IMMEDIATE 'DROP USER ' || SEI_USER || ' CASCADE';
        dbms_output.put_line('  UserName "' || SEI_USER || ' dropped');
    ELSE
        dbms_output.put_line('  The UserName "' || SEI_USER || ' doesn''t exists');
    END IF;
    
    -- Main TableSpace
    IF SEI_TABLE_SPACE is not null THEN
        BEGIN
            EXECUTE IMMEDIATE 'DROP TABLESPACE '
                                || SEI_TABLE_SPACE
                                || ' INCLUDING CONTENTS AND DATAFILES CASCADE CONSTRAINTS';
                dbms_output.put_line('  TableSpace "' || SEI_TABLE_SPACE || '" dropped');
            EXCEPTION
                WHEN TablespaceDOESNTExistsExcep THEN
                    dbms_output.put_line('  The TableSpace "' || SEI_TABLE_SPACE || '" doesn''t exists');
                    NULL;
            END;
        ELSE
            dbms_output.put_line('  The SEI_TABLE_SPACE variable was not filled so tablespace will not be dropped');
    END IF;
    
    -- Temp TableSpace
    IF SEI_TMP_TABLE_SPACE is not null THEN
        BEGIN
            EXECUTE IMMEDIATE 'DROP TABLESPACE '
                                || SEI_TMP_TABLE_SPACE
                                || ' INCLUDING CONTENTS AND DATAFILES CASCADE CONSTRAINTS';
                dbms_output.put_line('  TableSpace "' || SEI_TMP_TABLE_SPACE || '" dropped');
            EXCEPTION
                WHEN TablespaceDOESNTExistsExcep THEN
                    dbms_output.put_line('  The TableSpace "' || SEI_TMP_TABLE_SPACE || '" doesn''t exists');
                    NULL;
            END;
        ELSE
            dbms_output.put_line('  The SEI_TABLE_SPACE variable was not filled so tablespace will not be dropped');
    END IF;
END;

Informations supplémentaires sur Oracle

Veuillez consulter les sections ci-dessous pour obtenir des informations supplémentaires sur Oracle :

Définitions des composants Oracle

SID : ID de système Oracle. Il identifie de manière unique une base de données (par exemple : ORCL).
Utilisateur : Les utilisateurs et les schémas sont essentiellement la même chose. Un utilisateur est le compte que vous utilisez pour vous connecter à une base de données, et un schéma est l'ensemble des objets (tables, vues, etc.) qui appartiennent à ce compte.
Tablespace : Une base de données Oracle est constituée d'une ou plusieurs unités de stockage logiques appelées tablespaces, qui stockent collectivement toutes les données de la base de données. Chaque tablespace est constitué d'un ou plusieurs fichiers appelés datafiles, qui sont des structures physiques conformes au système d'exploitation sur lequel fonctionne Oracle.

Note
SEI prend en charge les fonctionnalités de tablespace Oracle telles que DEFAULT ROW STORE COMPRESS ADVANCED. Cependant, de nombreuses fonctionnalités de tablespace Oracle (y compris celle mentionnée précédemment) sont des fonctionnalités supplémentaires qui doivent être achetées séparément auprès d'Oracle. Veuillez contacter votre administrateur de bases de données Oracle si vous souhaitez en savoir plus sur l'achat de licences pour des fonctionnalités supplémentaires de tablespace.
Temp Tablespace : Un tablespace temporaire, comme son nom l'indique, stocke les données temporaires qui n'existent que pendant la session de la base de données. Oracle utilise les tablespaces temporaires pour améliorer la simultanéité des opérations de tri multiples qui ne tiennent pas en mémoire. Le temp tablespace peut être partagé par plusieurs utilisateurs.
Datafile : Les datafiles sont des fichiers physiques du système d'exploitation qui stockent les données de toutes les structures logiques de la base de données. Ils doivent être créés explicitement pour chaque tablespace. Oracle attribue à chaque datafile deux numéros de fichier, un numéro de fichier absolu et un numéro de fichier relatif, qui sont utilisés pour l'identifier de manière unique. Plusieurs datafiles peuvent être ajoutés au même tablespace (régulier ou temporaire).
Block Size : Taille du bloc pour les données. La taille du bloc peut être différente selon le tablespace mais elle est généralement la même. La taille du bloc aura un impact direct sur la taille maximale du datafile.

Stockage

Block Size : La taille du bloc par défaut est souvent de 8 Ko donc le datafile a un maximum de 32 Go.

Pour obtenir la taille de bloc actuelle de la base de données, exécutez la commande SQL suivante :

select value from v$parameter where name = 'db_block_size';

Taille du bloc	Taille maximum du datafile	Taille maximum de la base de données
2 Ko	8 Go	512 To
4 Ko	16 Go	1 Po
8 Ko	32 Go	2 Po
16 Ko	64 Go	4 Po
32 Ko	128 Go	8 Po

Tablespace et datafile : Par défaut, le tablespace ne contient qu'un seul datafile. En fonction de la taille du bloc, la taille par défaut d'un tablespace sera seulement de 32 Go. Vous devez ajouter des datafiles à un tablespace pour stocker davantage de données (tablespace régulier ou temporaire). Le nombre maximum de datafiles qui peuvent être ajoutés est de 65 536 fichiers par base de données, d'où la taille maximale de la base de données mentionnée ci-dessus (par exemple : 32 Go x 65 536 = 2 Po). Le nombre maximum de datafiles dans un tablespace est de 1022 (32 To pour un bloc de 8 Ko).

Pour ajouter des datafiles à un tablespace, exécutez la commande SQL suivante (ajustez cette commande avec votre propre nom et les tailles souhaitées) :

ALTER TABLESPACE YOUR_TABLE_SPACE ADD DATAFILE YOURNAME.DBF' size 1024m autoextend on maxsize 32767m;

Pour obtenir la liste des fichiers de données attachés à un tablespace, exécutez la commande SQL suivante :

SELECT TABLESPACE_NAME,FILE_NAME From DBA_DATA_FILES;
Temp tablespace : Le tablespace temporaire peut devenir très grand une fois que le gestionnaire OLAP a chargé les données (chargement complet). Cependant, l'espace utilisé reste stable pour les chargements suivants car il ne sera plus alloué.

Oracle utilise des tablespaces temporaires pour améliorer la simultanéité des opérations de tri multiples qui ne tiennent pas en mémoire. En outre, Oracle stocke des tables temporaires, des index temporaires, des B-trees temporaires et des LOBs temporaires dans des tablespaces temporaires.

Pour voir l'allocation d'espace d'un tablespace temporaire, exécutez la commande suivante :

SELECT * FROM dba_temp_free_space;

Pour ajouter des fichiers de données à un tablespace existant, exécutez le SQL suivant (ajustez cette commande avec votre propre nom et les tailles souhaitées) :

ALTER TABLESPACE YOUR_TABLE_SPACE ADD TEMPFILE 'YOURNAME.DBF' size 1024m autoextend on maxsize 32767m ;

Journalisation et compression

Journalisation : Dans Oracle, la journalisation est activée par défaut lors de la création du tablespace. Dans le cas de l'entrepôt de données, la journalisation n'est pas nécessaire car nous rechargeons simplement l'entrepôt de données au lieu d'utiliser la fonction annuler/refaire. La journalisation ayant un impact direct sur la taille du tablespace temporaire, il est recommandé de la désactiver dans la mesure du possible.

Pour créer un nouveau tablespace sans journalisation, exécutez cette commande :

create tablespace your_table_space datafile 'your_name.DBF' size 1024m autoextend on maxsize 32767m NOLOGGING;

Pour supprimer la journalisation d'un tablespace:

ALTER TABLESPACE SEICUBE3 NOLOGGING;

Compression: Il existe plusieurs façons de compresser des données dans Oracle, mais celle que nous décrivons ici pour SEI est Advanced Row Compression. Advanced Row Compression a plusieurs avantages. Un avantage significatif est la capacité d'Oracle à lire les blocs compressés (données et index) directement en mémoire, sans décompresser les blocs. Cela améliore les performances grâce à la réduction des entrées/sorties, et à la réduction des appels système liés aux opérations d'entrée/sortie. De plus, le cache tampon devient plus efficace en stockant les données sans avoir à ajouter de la mémoire.

Pour créer un nouveau tablespace avec compression et sans journalisation, exécutez cette commande :

create tablespace your_table_space datafile 'your_name.DBF' size 1024m autoextend on maxsize 32767m DEFAULT ROW STORE COMPRESS ADVANCED NOLOGGING;

Le tableau ci-dessous décrit un test de journalisation et de compression sur un cube dont la base de données source comportait plus de 190 millions de lignes. La tranche maîtresse générée contenait 111 millions de rangs et 3 autres tranches contenaient plus de 94 millions de rangs. Tous les scénarios montrent clairement que la compression doit être désactivée. Il est fortement recommandé d'utiliser la compression car le temps de chargement n'était pas très différent et le stockage était grandement réduit.

Taille du bloc	Compression	Journalisation	Temps de chargement	Taille du tablespace temporaire	Taille des données	Total
8 Ko	Oui	Oui	1h28	24.7 TB?	68.8 TB?	93.5 TB?
8 Ko	Non	Oui	1h16	83.2	106	189.2
8 Ko	Oui	Non	1h28	25.2	70.2	95.4
8 Ko	Non	Non	1h12	28	108	136
16 Ko	Non	Non	1h12	25.2	106	131.2

Sécurité

Utilisateur et accès : Les utilisateurs sont créés sans accès à SEI par défaut. Vous devez créer un utilisateur spécifique SEI dans la configuration de la source de données pour éviter des limitations au niveau du tablespace.

Pour créer un utilisateur et attacher le tablespace créé, exécutez cette commande :

CREATE USER YOUR_USER IDENTIFIED BY YOUR_PASSWORD DEFAULT TABLESPACE YOUR_TABLESPACE

TEMPORARY TABLESPACE YOUR_TEMP_TABLESPACE_TMP QUOTA UNLIMITED ON YOUR_TABLESPACE;

Après avoir créé l'utilisateur SEI, vous devez lui accorder l'accès minimum suivant :

GRANT create procedure, create session, create table, connect,

create type, create view, create synonym, create trigger, resource TO YOUR_USER;

Note
Pour toute source de données Oracle, l'utilisateur SEI doit être mis en tant que schéma personnalisé dans la définition de la source de données. Cela permettra à la table de suivi ou aux objets personnalisés d'être créés dans cet utilisateur spécifique au lieu de la source. Les déclencheurs (triggers) sont la seule exception à cette règle.

Vous devez également accorder à l'utilisateur SEI accès en lecture tous les utilisateurs Oracle (bases de données) que vous voudrez lire comme source. Le niveau d'accès dépendra de ce que vous voulez faire (lecture seule, créer un cube OLAP, réécrire, etc.).

Pour accorder à l'utilisateur SEI accès à une source, exécutez cette commande (modifiez SOURCE_USER et YOUR_USER) :

begin

for x in ( SELECT TABLE_NAME FROM DBA_TABLES WHERE OWNER = SOURCE_USER' )

loop

BEGIN

execute immediate 'GRANT SELECT ON SOURCE_USER.”' || x.TABLE_NAME || '” TO YOUR_USER';

END;

end loop;

end;

begin

for x in ( select VIEW_NAME from DBA_VIEWS WHERE OWNER = ' SOURCE_USER ' )

loop

BEGIN

execute immediate 'grant select on SOURCE_USER. ”' || x.VIEW_NAME || '” to YOUR_USER ';

END;

end loop;

end;
Déclencheurs : Les déclencheurs doivent être créés directement dans la configuration des utilisateurs SEI à partir du Gestionnaire OLAP Gestionnaire OLAP avec le niveau d'accès approprié. Ceci est nécessaire pour éviter le cas où l'ERP insère des lignes dans une table avec un déclencheur qui n'aura pas l'accès approprié aux tables de suivi.

Pour ajouter le niveau d'autorisation approprié à l'utilisateur :

grant create any trigger to YOUR_USER;

La source de données est configurée avec le schéma de SEI et l'utilisateur SEI. Vous devez indiquer SEED dans le schéma source et SEICube dans le schéma SEI.

Lorsque vous construirez le cube OLAP, la table de suivi et le déclencheur seront créés dans l'utilisateur SEI, et aucune table ne sera créée dans l'utilisateur source. Le déclencheur aura donc automatiquement accès à la table de suivi.

Lorsqu'un enregistrement est inséré dans l'utilisateur source (ex : SEED.GACCENTRYD) à partir d'un utilisateur source (ex : SEED), les données seront insérées et le trigger sera exécuté avec l'autorisation de l'utilisateur SEI puisqu'il réside dans l'utilisateur source.